FusionCharts

Here, we'll see how to generate a combination chart dynamically from a database.

We'll plotting a 3D Column Line Dual Y axis combination chart showing the Top 5 customers for a particular year. On the primary axis, we'll have the Amount figure representing the amount (in dollars) which has been transacted with that customer. On the secondary axis, we'll have Quantity axis representing the quantity traded for that year for that particular customer. The end chart would look as under:

As you can see above, we've extracted the amount and quantity figure for the top 5 customers for a particular year. All this data is contained in a view called Invoices. The entire XML code required for the above chart is as under (say for the year 1997):

In the above XML, we first define the basic attributes (both functional and visual) of the <graph> element. Thereafter, we render the <categories> elements. Each <category> element represents a category of data (in our example it's the top five customers whose data we're comparing). We've shown only the first 5 characters of the customer name, followed by ellipses, instead of the full customer name to avoid cluttering on the chart. We're showing the full customer name as tool tip. Post that, we render two <dataset> blocks - one for primary axis representing Amount figure and the second for the secondary axis representing the Quantity axis.

Let's now quickly code this chart in ASP using dataURL method. It's always recommended to use the dataURL method when working with combination charts too, as the XML data document tends to get larger in size and as such, older versions of browsers are not very able to handle long data chunks in the same page.

As we had earlier seen, the dataURL method requires two pages:

Chart Container Page - This page contains the chart object alongwith any other HTML objects. We'll name this page as Chart.asp - in this page, we let the user select the year for which he wants to view the chart and would show the chart.
Data Provider Page - This page provides the XML data required by the chart. This page is invoked by FusionCharts contained in Chart.asp. We'll name this page as Data.asp.

The above two are present in the downloads under the folder FusionCharts2_3 > Sample Code > DBExamples > ASP > Combination. We also have a sample of another combination chart, with multiple series on a single axis under the folder FusionCharts2_3 > Sample Code > DBExamples > ASP > Combination2.

We'll also need two other pages:

Includes/Connection_inc.asp - This page contains the data connection string
Includes/FC_Colors.asp - This page contains a list of hex colors (without #) in an array named as arr_FCColors

The above two include files are present in a common Includes folder at FusionCharts2_3 > Sample Code > DBExamples > ASP > Includes.

FC_Colors.asp looks as under:

<%
'This page contains an array of colors to be used as default set of colors for FusionCharts
'arr_FCColors is the array that would contain the hex code of colors
'ALL COLORS HEX CODES TO BE USED WITHOUT #
Dim arr_FCColors(20), intFCColors_count
'Count of the number of colors
intFCColors_count = 20
arr_FCColors(1) = "AFD8F8"
arr_FCColors(2) = "F6BD0F"
arr_FCColors(3) = "8BBA00"
arr_FCColors(4) = "A66EDD"
arr_FCColors(5) = "F984A1"
arr_FCColors(6) = "CCCC00" 'Chrome Yellow+Green
arr_FCColors(7) = "999999" 'Grey
arr_FCColors(8) = "0099CC" 'Blue Shade
arr_FCColors(9) = "FF0000" 'Bright Red
arr_FCColors(10) = "006F00" 'Dark Green
arr_FCColors(11) = "0099FF" 'Blue (Light)
arr_FCColors(12) = "FF66CC" 'Dark Pink
arr_FCColors(13) = "669966" 'Dirty green
arr_FCColors(14) = "7C7CB4" 'Violet shade of blue
arr_FCColors(15) = "FF9933" 'Orange
arr_FCColors(16) = "9900FF" 'Violet
arr_FCColors(17) = "99FFCC" 'Blue+Green Light
arr_FCColors(18) = "CCCCFF" 'Light violet
arr_FCColors(19) = "669900" 'Shade of green
arr_FCColors(20) = "1941A5" 'Dark Blue
%>

Basically, this file is a list of hex colors that we'll be using for the chart. In the above list, we've stored only 20 colors. You can extend it to any number. You should note that all the above colors are without the #. We'll include this file in all our pages, where we generate the XML data for FusionCharts.

Connection_inc.asp is the page which contains the database connection string. When you run the code on your machine, after downloading the package, you should ensure that this page is updated so as to reflect the connection details to your SQL server. This page looks as under:

<%
'*****************************************************************************************
' Page Description: This page contains the database connections
'*****************************************************************************************

'***** SQL SERVER FORMAT *****
'Update the string, replacing the words YourServerName, YourDatabaseName, YourUsername, and YourPassword
'with the appropriate values.
Const DB_CONNECTION = "Driver=SQL Server;Server=(local);Initial Catalog=Northwind;UID=sa;PWD="

Response.Write vbcrlf
%>

The page Data.asp is responsible for relaying virtual XML documents to the FusionCharts embedded in Chart.asp. You should note that Data.asp does NOT write XML data documents to the server disk physically. It relays the XML data document virtually (i.e., no XML files are created and saved on the server). The code for this page can be reproduced as under:

<%@ Language=VBScript %>


<%
   'Request the current year from querystring
   'The year was passsed to this page in the form Data.asp?Year=199x (where x=6,7,8)
   Dim intYear, strDataURL
   intYear = Request("Year")

   'Define database objects
   'oRs - Recordset object
   'strSQL - String variable to contain the SQL query
   'intCounter - Numeric value to keep a track of number of records
   Dim oRs, strSQL, intCounter
   intCounter = 0
   'Initialize the database objects
   Set oRs = Server.CreateObject("ADODB.Recordset")

   'strXMLData - String variable to contain the entire XML data document for the chart
   'strCategories - String variable to store the <categories> element and it's child <category> elements.
   'strAmountDS - String variable to store the amount <dataset>
   'strQuantityDS - String variable to store Quantity dataset
   Dim strXMLData, strCategories, strAmountDS, strQuantityDS
   'Initialize the <graph> element
   strXMLData = "<graph PYAxisName='Amount' SYAxisName='Quantity' showvalues='0' rotateNames='0' showAnchors='1' decimalPrecision='2' limitsDecimalPrecision='0' divLineDecimalPrecision='0' hoverCapSepChar=' ' showShadow='0' lineThickness='3'>" & vbCrlf
   'Initiate <categories> element
   strCategories = "<categories>" & vbCrlf
   'Initialize the amount and quantityt dataset
strAmountDS = "<dataset seriesname='' showValue='1' color='" & arr_FCColors(1) & "' numberPrefix='$' >" & vbCrlf
strQuantityDS = "<dataset seriesname='' showValue='1' color='" & arr_FCColors(4) & "' parentYAxis='S' numberSuffix=' pcs.' anchorSides='12' anchorRadius='3' anchorBorderColor='" & arr_FCColors(4) & "'>" & vbCrlf
   'Get a list of all the years
   strSQL = "SELECT TOP 5 CustomerName, SUM(ExtendedPrice) As Total, SUM(Quantity) As Quantity, SUM(Discount*ExtendedPrice) As Discount FROM Invoices WHERE YEAR(OrderDate)=" & intYear & " GROUP BY CustomerName ORDER BY SUM(ExtendedPrice) DESC"
   oRs.Open strSQL, DB_CONNECTION
   While not oRs.EOF
      'Increment the counter
      intCounter = intCounter + 1
      'Generate the <category> element
      strCategories = strCategories & "<category name='" & Left(oRs("CustomerName"), 6) & "...' hoverText='" & oRs("CustomerName") & "'/>" & vbCrlf
      'Generate the set element for both amount and quantity dataset
      strAmountDS = strAmountDS & "<set value='" & oRs("Total") & "' />" & vbCrlf
      strQuantityDS = strQuantityDS & "<set value='" & oRs("Quantity") & "' />" & vbCrlf
      oRs.MoveNext()
Wend
   'Close the category and dataset elements
   strCategories = strCategories & "</categories>" & vbCrlf
   strAmountDS = strAmountDS & "</dataset>" & vbCrlf
   strQuantityDS = strQuantityDS & "</dataset>" & vbCrlf
   'Generate the XML document by concatenating the strings we've generated. Also, close the <graph> element.
   strXMLData = strXMLData & strCategories & strAmountDS & strQuantityDS & "</graph>"
   'Destroy the recordset objects
   Set oRsYears = nothing
   Set oRs = nothing
   'Write the XML data to output stream
   Response.Write(strXMLData)
%>

In the above code, we're doing the following:

We first request the year, for which we have to show the data. The year was passed in the format Data.asp?year=1996 (or 1997 or 1998) by the FusionCharts charts contained in the page Chart.asp
Next, we initialize a few string variables which would be used to contain the XML data. strXMLData will be used to contain the entire XML data document for the chart. strCategories will be used to store the <categories> element and it's child <category> elements. strAmountDs will be used to store the amount <dataset> and <set> elements. strQuantityDs will be used to store the quantity <dataset> and <set> elements.
We now initialize the <graph> element in the variable strXMLData and opening <categories> tag in the variable strCategories.
We also initialize the opening <dataset> tags for both dataset blocks in the variables strAmountDS and strQuantityDS. The first dataset has been set with a parentYAxis attribute as P (primary) and the second one with S (secondary).
Next, we retrieve the recordset from the database for top 5 customers for the selected year and iterate through the records one by one. For each record, we add a <category> element to the variable strCategories, and <set> elements in the format <set value='xxx' /> to the variables strAmountDS and strQuantityDS.
Finally, we close all the open elements in the XML data document (like <categories>, <dataset> and <graph>) using simple string concatenation and form a full XML doc in strXMLData.
In the end, we just write this XML data document to the output stream.

When you try viewing this page individually in the browser (in the format http://localhost/...Path.../DBExamples/ASP/Combination/Data.asp?year=1997) you'll get the XML output which we had earlier seen. You should always make sure, that while using dataURL method, your dataURL script should output just XML data and no HTML tags.

Let's now shift our attention to Chart.asp and see the code it contains to embed the chart.

Chart.asp contains the following code:

<%@ Language=VBScript %>
<html>
<head>
<title>FusionCharts</title>
<link REL="Stylesheet" HREF="../Style.css">
</head>

<%
   'Request the current year from querystring
   Dim intYear, strDataURL
   intYear = Request("Year")
   'Database objects
   'oRsYears - Recordset Object
   'strSQL - String variable to hold SQL Query (to get all years list)
   Dim oRsYears, strSQL
   'Initialize the recordset object and retrieve the years
   Set oRsYears = Server.CreateObject("ADODB.Recordset")
   strSQL = "SELECT DISTINCT YEAR(OrderDate) As Year FROM Orders ORDER BY 1"
   oRsYears.Open strSQL, DB_CONNECTION
   'If no years has been specified select the last one
   If intYear="" then
      While not oRsYears.EOF
         intYear = oRsYears("Year")
         oRsYears.MoveNext()
      Wend
   end if
   'Move to first
   oRsYears.MoveFirst()
   'Define dataURL
   strDataURL = "Data.asp?Year=" & intYear
   'URL Encode the dataURL - Important Step
   strDataURL = Server.URLEncode(strDataURL)
%>
<table width="500" border="0" cellpadding="2" cellspacing="0" class="tableWithBorder" align="center">
   <tr>
      <td colspan="3" class="trdark"><div align="center"><span class="textboldlight">FusionCharts</span></div></td>
   </tr>
   <form action="Chart.asp" method="post" id="form1" name="form1">
   <tr>
      <td colspan="3" class="text" align="center">Please select the year for which you want to see the chart:
      <select name="year" class="select" onChange="this.form.submit();">
      <%
         While not oRsYears.EOF
      %>
            <option value="<%=oRsYears("Year")%>" <% If int(intYear)=int(oRsYears("Year")) then %> selected <% end if %>><%=oRsYears("Year")%>
         </option>
      <%
            oRsYears.MoveNext()
         Wend
      %>
      </select>
      </td>
   </tr>
   </form>
   <tr>
      <td colspan="3"> </td>
   </tr>
   <tr>
      <td valign="top">
         <table width="98%" border="0" cellspacing="0" cellpadding="2" align="center">
            <tr>
               <td>
               <div align="center" class="text">
               <object classid="clsid:D27CDB6E-AE6D-11cf-96B8-444553540000" codebase="http://download.macromedia.com/pub/shockwave/cabs/
flash/swflash.cab#version=6,0,0,0" WIDTH="500" HEIGHT="300" id="FusionCharts" ALIGN VIEWASTEXT>
               <param NAME="FlashVars" value="&dataURL=<%=strDataURL%>">
               <param NAME="movie" VALUE="../../../Charts/FC_2_3_MSColumnLine_DY_3D.swf?chartWidth=500&chartHeight=300">
               <param NAME="quality" VALUE="high">
               <param NAME="bgcolor" VALUE="#FFFFFF">
               <embed src="../../../Charts/FC_2_3_MSColumnLine_DY_3D.swf?chartWidth=500&chartHeight=300" FlashVars="&dataURL=<%=strDataURL%>" quality="high" bgcolor="#FFFFFF" WIDTH="500" HEIGHT="300" NAME="FusionCharts" ALIGN TYPE="application/x-shockwave-flash" PLUGINSPAGE="http://www.macromedia.com/go/getflashplayer">
               </object>
               </div>
               </td>
            </tr>
         </table>
      </td>
   </tr>
</table>
<p align="center" class="text">©All Rights Reserved - InfoSoft Global Private Limited - 2005 - <a href="http://www.InfoSoftGlobal.com" target="_blank">www.InfoSoftGlobal.com</a></p>
</body></html>
<%
   'Destroy objects
   Set oRsYears = nothing
%>

Here, in the above code, we're doing the following:

First, we're requesting a list of unique years from the database and rendering them in a drop down box. By default, we choose the last year as the selected year (i.e., the year for which we'll show the chart) and store it in the variable intYear. When the user selects a different year from the drop down box, the forms submits to this page only and the new requested year is stored in the variable intYear.
Next, we generate the dataURL string in the format Data.asp?year=(intYear) (i.e., Data.asp?year=1996)
Thereafter, we embed the FusionCharts chart in this page and provide the above dataURL to it (see the code in bold above).

When you now view Chart.asp, you'll get the following chart: